查看: 108399 | 回复: 6

风筝

发表于: 2022-11-8 13:58:00 | 显示全部楼层

楼主

MAX30102脉搏血氧和心率传感器是一款基于I2C的低功耗即插即用型生物识别传感器。想要将实时心率数据整合到项目中的学生、爱好者、工程师、创客以及游戏和移动开发人员可以使用它。

MAX30102模块硬件概述

该模块采用MAX30102（MAX30100的升级产品） - ADI公司的现代集成脉搏血氧计和心率传感器。它包含了两个LED、一个光电探测器、优化的光学器件和低噪声模拟信号处理来检测脉搏血氧饱和度 (SpO2) 和心率 (HR) 信号。

MAX30102有两个LED：红色LDE和红外LED。模块另一边是一个非常灵敏的光电探测器。当点亮LED时，检测反射回探测器的光量，然后根据特征，你可以测量血氧值和心率。

电源

MAX30102模块需要两种不同的电源电压：传感器为1.8V，红色LED和红外LED为3.3V。所以模块自带3.3V和1.8V稳压器。

在电路板背面，您会发现一个焊接跳线，可用于在3.3V和1.8V逻辑电平之间进行选择。默认选择与 Arduino的逻辑电平兼容的3.3V逻辑电平。但您也可以根据需要选择1.8V逻辑电平。这允许您将模块连接到任何具有5V、3.3V甚至1.8V电平I/O的微控制器。

MAX30102 最重要的特性之一是其低功耗：MAX30102在测量期间的功耗低于600μA。也可以将MAX30102置于待机模式，其功耗仅为0.7μA。这种低功耗允许在手机、可穿戴设备或智能手表等电池供电设备中实现。

片上温度传感器

MAX30102具有片上温度传感器，可用于补偿环境变化和校准测量值。

这是一款相当精确的温度传感器，可测量 -40˚C 至 +85˚C 范围内的芯片温度，精度为±1˚C。

I2C接口

该模块使用简单的两线I2C接口与微控制器通信。它有一个固定的I2C地址：0xAE（用于写操作）和 0xAF（用于读操作）。

FIFO缓冲器

MAX30102嵌入了一个FIFO缓冲器，用于存储数据样本。FIFO有一个32个样本的存储库，这意味着它可以容纳多达32个SpO2和心率样本。FIFO缓冲器可以减轻微控制器从传感器读取每个新数据样本的负担，从而节省系统功耗。

中断

MAX30102可以编程产生中断，允许主机微控制器在传感器收集数据的同时执行其他任务。可以为5个不同的源启用中断：

● 电源就绪：上电或掉电后触发。

● 新数据就绪：在收集每个SpO2和HR数据样本后触发。

● 环境光消除：当 SpO2/HR 光电二极管的环境光消除功能达到最大限制时触发，影响ADC的输出。

● 温度就绪：当内部芯片温度转换完成时触发。

● FIFO已满：当FIFO已满且未来数据即将丢失时触发。

INT引脚是漏极开路，因此使用板载电阻拉高。当中断发生时，INT引脚变为低电平并保持低电平，直到中断被清除。

MAX30102脉搏血氧和心率传感器如何工作？

MAX30102或任何光学脉搏血氧和心率传感器由一对高强度LED（红色和红外LED，均为不同波长）和一个光电探测器组成。这些LED的波长分别为660nm和880nm。

MAX30102的工作原理是将两种光都照射到手指或耳垂上并使用光电探测器测量反射光量。这种通过光检测脉冲的方法称为光电体积描记图（Photoplethysmogram）。

MAX30102的工作可分为两部分：心率测量和脉搏血氧饱和度（测量血液中的氧含量）。

心率测量

动脉血中的氧合血红蛋白（HbO2）具有吸收红外光的特性。血液越红（血红蛋白越高），吸收的红外光越多。当血液随着每次心跳泵入手指时，反射光的量会发生变化，从而在光电探测器的输出端产生变化的波形。当您继续照射光并获取光电探测器读数时，您很快就会开始获得心跳 (HR) 脉搏读数。

Pulse-Detection-Heart-Rate-Sensor-Working-Photoplethysmogram.jpg

脉搏血氧

脉搏血氧（Pulse Oximetry）的原理是，吸收的红光和红外光量取决于血液中的氧气量。下图是含氧血红蛋白 (HbO2) 和脱氧血红蛋白 (Hb) 的吸收光谱。

从图中可以看出，脱氧血液吸收更多红光（660nm），而含氧血液吸收更多红外光（880nm）。通过测量光电探测器接收到的红外和红光的比率，可以计算出血液中的氧气水平 (SpO2)。

MAX30102模块引脚

MAX30102模块提供以下连接。

● VIN 是电源引脚。您可以将其连接到Arduino的3.3V或5V输出。

● SCL 是I2C时钟引脚，连接到Arduino的I2C时钟线。

● SDA 是I2C数据引脚，连接到Arduino的I2C数据线。

● INT MAX30102可以编程为每个脉冲产生一个中断。这条线是开漏的，所以使用板载电阻拉高。当中断发生时，INT引脚变为低电平并保持低电平，直到中断被清除。

● IRD MAX30102集成了一个LED驱动器，用于驱动LED脉冲，用于SpO2和HR测量。

● RD 引脚类似于IRD引脚，但用于驱动红色LED。如果您不想自己驱动红色 LED，请将其悬空。

● GND 是接地引脚。

将MAX30102模块连接到Arduino

首先将VCC引脚连接到电源，3V-5V就可以了。使用与微控制器逻辑所基于的电压相同的电压。对于大多数 Arduino 来说，这是5V。对于3.3V逻辑器件，使用3.3V。现在将GND连接到公共地。

将SCL引脚连接到Arduino上的I2C时钟引脚，将SDA引脚连接到I2C数据引脚。请注意，每个Arduino开发板都有不同的I2C引脚，应相应地连接。下图显示了接线。

Arduino-Wiring-for-MAX30102-Pulse-Oximeter-Heart-Rate-Module.jpg

安装库

MAX30102传感器有多个库可用。然而，在示例中，我们使用的是SparkFun Electronics提供的库。该库公开了MAX30102的大部分特性，并提供简单易用的函数来计算脉率和SpO2。您可以从Arduino IDE库管理器中下载此库。

要安装库，请导航到 Sketch > Include Library > Manage Libraries… 等待库管理器下载库索引并更新已安装库的列表。

输入MAX3010x筛选搜索结果。查找SparkFun MAX3010x Pulse and Proximity Sensor Library。单击该条目，然后选择安装。

电梯直达

使用道具举报

风筝

发表于: 2022-11-8 14:34:20 | 显示全部楼层

沙发

MAX30102示例草图

SparkFun_MAX3010x库有许多示例草图。您可以使用这些示例草图作为开发您自己的代码的基础。

要访问示例草图，请导航至File > Examples > SparkFun MAX3010x Pulse and Proximity Sensor Library。您将看到一系列示例草图。

示例1 – 读取红灯和红外LED

第一个示例输出传感器读取的原始值（IR和红灯读数）。将其上传到Arduino并打开串口终端查看打印值。

#include <Wire.h>
#include "MAX30105.h"
MAX30105 particleSensor;
void setup() {
Serial.begin(9600);
// Initialize sensor
if (particleSensor.begin() == false) {
Serial.println("MAX30102 was not found. Please check wiring/power.");
while (1);
}
particleSensor.setup(); //Configure sensor. Use 6.4mA for LED drive
}
void loop() {
Serial.print(" R[");
Serial.print(particleSensor.getRed());
Serial.print("] IR[");
Serial.print(particleSensor.getIR());
Serial.println("]");
}

复制代码

使传感器朝上，在传感器上滑动手掌。当您的手反射不同数量的光时，您应该会看到值的变化。

如果您只查看值，串口数据可能很难可视化。如果您使用的是Arduino IDE v1.6.6+，则可以选择使用Arduino串口绘图仪（Serial Plotter）查看图表上的数据。

首先，将上面代码中的loop()函数替换为以下代码片段：

void loop() {
Serial.print(particleSensor.getRed());
Serial.print(", ");
Serial.println(particleSensor.getIR());
}

复制代码

在 Arduino IDE 中，选择Tools > Serial Plotter。当您将手滑过传感器时，您应该会看到类似于下图的波浪。

示例2 – 存在感测

我们的下一个实验展示了如何将MAX30102传感器用作通用接近传感器或反射传感器，并可作为更多实际实验和项目的基础。

此示例通过在设置期间获取少量读数并将它们平均在一起来工作。然后它使用这个平均值作为基线。如果传感器检测到与平均值相比有显着变化，则打印“Something is there!”。

#include <Wire.h>
#include "MAX30105.h"
MAX30105 particleSensor;
long samplesTaken = 0; //Counter for calculating the Hz or read rate
long unblockedValue; //Average IR at power up
long startTime; //Used to calculate measurement rate
void setup() {
Serial.begin(9600);
// Initialize sensor
if (particleSensor.begin(Wire, I2C_SPEED_FAST) == false) { //Use default I2C port, 400kHz speed
Serial.println("MAX30102 was not found. Please check wiring/power. ");
while (1);
}
//Setup to sense up to 18 inches, max LED brightness
byte ledBrightness = 0xFF; //Options: 0=Off to 255=50mA
byte sampleAverage = 4; //Options: 1, 2, 4, 8, 16, 32
byte ledMode = 2; //Options: 1 = Red only, 2 = Red + IR, 3 = Red + IR + Green
int sampleRate = 400; //Options: 50, 100, 200, 400, 800, 1000, 1600, 3200
int pulseWidth = 411; //Options: 69, 118, 215, 411
int adcRange = 2048; //Options: 2048, 4096, 8192, 16384
//Configure sensor with these settings
particleSensor.setup(ledBrightness, sampleAverage, ledMode, sampleRate, pulseWidth, adcRange);
particleSensor.setPulseAmplitudeRed(0); //Turn off Red LED
particleSensor.setPulseAmplitudeGreen(0); //Turn off Green LED
//Take an average of IR readings at power up
unblockedValue = 0;
for (byte x = 0 ; x < 32 ; x++) {
unblockedValue += particleSensor.getIR(); //Read the IR value
}
unblockedValue /= 32;
startTime = millis();
}
void loop() {
samplesTaken++;
Serial.print("IR[");
Serial.print(particleSensor.getIR());
Serial.print("] Hz[");
Serial.print((float)samplesTaken / ((millis() - startTime) / 1000.0), 2);
Serial.print("]");
long currentDelta = particleSensor.getIR() - unblockedValue;
Serial.print(" delta[");
Serial.print(currentDelta);
Serial.print("]");
if (currentDelta > (long)100) {
Serial.print(" Something is there!");
}
Serial.println();
}

复制代码

再次在传感器上滑动手掌，您将在串口终端上看到Something is there!消息。尝试测试传感器可以检测到某物的范围。

示例3 – 读取温度

我们的下一个示例以摄氏度和华氏度输出板载温度传感器的读数。虽然温度读数应用于校准HR和SpO2测量值，但如果您需要灵敏且响应快速的温度传感器，它会很有用。

#include <Wire.h>
#include "MAX30105.h"
MAX30105 particleSensor;
void setup() {
Serial.begin(9600);
Serial.println("Initializing...");
// Initialize sensor
if (particleSensor.begin(Wire, I2C_SPEED_FAST) == false) { //Use default I2C port, 400kHz speed
Serial.println("MAX30102 was not found. Please check wiring/power. ");
while (1);
}
//The LEDs are very low power and won't affect the temp reading much but
//you may want to turn off the LEDs to avoid any local heating
particleSensor.setup(0); //Configure sensor. Turn off LEDs
particleSensor.enableDIETEMPRDY(); //Enable the temp ready interrupt. This is required.
}
void loop() {
float temperature = particleSensor.readTemperature();
Serial.print("temperatureC=");
Serial.print(temperature, 4);
float temperatureF = particleSensor.readTemperatureF();
Serial.print(" temperatureF=");
Serial.print(temperatureF, 4);
Serial.println();
}

复制代码

现在尝试用手指加热传感器或在传感器上轻轻吹气。您应该会看到类似下面的输出。

使用道具举报

风筝

发表于: 2022-11-8 14:38:48 | 显示全部楼层

板凳

示例4 – 测量心率 (BPM)

在此示例中，我们将测量人的心率（每分钟节拍数或BPM）。

#include <Wire.h>
#include "MAX30105.h"
#include "heartRate.h"
MAX30105 particleSensor;
const byte RATE_SIZE = 4; //Increase this for more averaging. 4 is good.
byte rates[RATE_SIZE]; //Array of heart rates
byte rateSpot = 0;
long lastBeat = 0; //Time at which the last beat occurred
float beatsPerMinute;
int beatAvg;
void setup() {
Serial.begin(115200);
Serial.println("Initializing...");
// Initialize sensor
if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) {
Serial.println("MAX30102 was not found. Please check wiring/power. ");
while (1);
}
Serial.println("Place your index finger on the sensor with steady pressure.");
particleSensor.setup(); //Configure sensor with default settings
particleSensor.setPulseAmplitudeRed(0x0A); //Turn Red LED to low to indicate sensor is running
particleSensor.setPulseAmplitudeGreen(0); //Turn off Green LED
}
void loop() {
long irValue = particleSensor.getIR();
if (checkForBeat(irValue) == true) {
//We sensed a beat!
long delta = millis() - lastBeat;
lastBeat = millis();
beatsPerMinute = 60 / (delta / 1000.0);
if (beatsPerMinute < 255 && beatsPerMinute > 20) {
rates[rateSpot++] = (byte)beatsPerMinute; //Store this reading in the array
rateSpot %= RATE_SIZE; //Wrap variable
//Take average of readings
beatAvg = 0;
for (byte x = 0 ; x < RATE_SIZE ; x++)
beatAvg += rates[x];
beatAvg /= RATE_SIZE;
}
}
Serial.print("IR=");
Serial.print(irValue);
Serial.print(", BPM=");
Serial.print(beatsPerMinute);
Serial.print(", Avg BPM=");
Serial.print(beatAvg);
if (irValue < 50000)
Serial.print(" No finger?");
Serial.println();
}

复制代码

上传草图后，将手指尽可能稳定地放在传感器上，等待几秒钟让读数有意义。你会看到这样的结果。

示例5 – 测量氧饱和度 (SpO2)

在我们的最后一个示例中，我们将测量人的血氧水平 (SpO2)。继续尝试草图。

#include <Wire.h>
#include "MAX30105.h"
#include "spo2_algorithm.h"
MAX30105 particleSensor;
#define MAX_BRIGHTNESS 255
#if defined(__AVR_ATmega328P__) || defined(__AVR_ATmega168__)
//Arduino Uno doesn't have enough SRAM to store 100 samples of IR led data and red led data in 32-bit format
//To solve this problem, 16-bit MSB of the sampled data will be truncated. Samples become 16-bit data.
uint16_t irBuffer[100]; //infrared LED sensor data
uint16_t redBuffer[100]; //red LED sensor data
#else
uint32_t irBuffer[100]; //infrared LED sensor data
uint32_t redBuffer[100]; //red LED sensor data
#endif
int32_t bufferLength; //data length
int32_t spo2; //SPO2 value
int8_t validSPO2; //indicator to show if the SPO2 calculation is valid
int32_t heartRate; //heart rate value
int8_t validHeartRate; //indicator to show if the heart rate calculation is valid
byte pulseLED = 11; //Must be on PWM pin
byte readLED = 13; //Blinks with each data read
void setup()
{
Serial.begin(115200); // initialize serial communication at 115200 bits per second:
pinMode(pulseLED, OUTPUT);
pinMode(readLED, OUTPUT);
// Initialize sensor
if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) //Use default I2C port, 400kHz speed
{
Serial.println(F("MAX30105 was not found. Please check wiring/power."));
while (1);
}
Serial.println(F("Attach sensor to finger with rubber band. Press any key to start conversion"));
while (Serial.available() == 0) ; //wait until user presses a key
Serial.read();
byte ledBrightness = 60; //Options: 0=Off to 255=50mA
byte sampleAverage = 4; //Options: 1, 2, 4, 8, 16, 32
byte ledMode = 2; //Options: 1 = Red only, 2 = Red + IR, 3 = Red + IR + Green
byte sampleRate = 100; //Options: 50, 100, 200, 400, 800, 1000, 1600, 3200
int pulseWidth = 411; //Options: 69, 118, 215, 411
int adcRange = 4096; //Options: 2048, 4096, 8192, 16384
particleSensor.setup(ledBrightness, sampleAverage, ledMode, sampleRate, pulseWidth, adcRange); //Configure sensor with these settings
}
void loop()
{
bufferLength = 100; //buffer length of 100 stores 4 seconds of samples running at 25sps
//read the first 100 samples, and determine the signal range
for (byte i = 0 ; i < bufferLength ; i++)
{
while (particleSensor.available() == false) //do we have new data?
particleSensor.check(); //Check the sensor for new data
redBuffer[i] = particleSensor.getRed();
irBuffer[i] = particleSensor.getIR();
particleSensor.nextSample(); //We're finished with this sample so move to next sample
Serial.print(F("red="));
Serial.print(redBuffer[i], DEC);
Serial.print(F(", ir="));
Serial.println(irBuffer[i], DEC);
}
//calculate heart rate and SpO2 after first 100 samples (first 4 seconds of samples)
maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
//Continuously taking samples from MAX30102. Heart rate and SpO2 are calculated every 1 second
while (1)
{
//dumping the first 25 sets of samples in the memory and shift the last 75 sets of samples to the top
for (byte i = 25; i < 100; i++)
{
redBuffer[i - 25] = redBuffer[i];
irBuffer[i - 25] = irBuffer[i];
}
//take 25 sets of samples before calculating the heart rate.
for (byte i = 75; i < 100; i++)
{
while (particleSensor.available() == false) //do we have new data?
particleSensor.check(); //Check the sensor for new data
digitalWrite(readLED, !digitalRead(readLED)); //Blink onboard LED with every data read
redBuffer[i] = particleSensor.getRed();
irBuffer[i] = particleSensor.getIR();
particleSensor.nextSample(); //We're finished with this sample so move to next sample
//send samples and calculation result to terminal program through UART
Serial.print(F("red="));
Serial.print(redBuffer[i], DEC);
Serial.print(F(", ir="));
Serial.print(irBuffer[i], DEC);
Serial.print(F(", HR="));
Serial.print(heartRate, DEC);
Serial.print(F(", HRvalid="));
Serial.print(validHeartRate, DEC);
Serial.print(F(", SPO2="));
Serial.print(spo2, DEC);
Serial.print(F(", SPO2Valid="));
Serial.println(validSPO2, DEC);
}
//After gathering 25 new samples recalculate HR and SP02
maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
}
}