风筝
发表于: 2018-11-6 21:19:15 | 显示全部楼层

在本篇文章中,我们将学习如何使用Arduino开发板控制可独立寻址的RGB LED灯或基于WS2812B的LED灯条。首先,我们通过一些基本示例阐释其工作原理,然后看一个非常酷的使用这些LED灯的Arduino项目 - DIY交互式LED咖啡桌。咖啡桌带有一颗WS2812B LED灯、用于检测物体的红外接近传感器和用于通过定制的Android应用程序控制颜色的HC-05蓝牙模块。

Creativity-Hero-LED-Table.jpg


WS2812B LED灯是如何工作的

让我们首先仔细看看LED灯条。它由5050型RGB LED灯组成,其中集成了非常紧凑的WS2812B LED驱动器IC。

WS2812B-LED-Driver-IC-5050-RGB-LED.jpg

根据三个红色、绿色和蓝色LED的强度,我们可以模拟出我们想要的任何颜色。

WS2812B-RGB-LEDs-work.jpg

使用这些LED灯的优点在于我们只需使用Arduino开发板上的一个引脚即可控制整个LED灯条。每个LED在每端有三个连接器接口,两个用于供电,一个用于数据。箭头表示数据流方向。前一个LED的数据输出焊盘连接到下一个LED的数据输入焊盘。我们可以将灯带切割成我们想要的任何尺寸,也可以使用电线增加LED灯距离。

How-to-Connect-WS2812B-LEDs-and-Arduino-Circuit-Schematic.png

至于供电,它们工作在5V,每个红色、绿色和蓝色LED需要大约20mA,或者在全亮度下每个LED总共60mA。请注意,当Arduino通过USB供电时,5V引脚只能处理大约400 mA的电流,当使用桶式电源连接器供电时,5V引脚可以处理大约900 mA的电流。因此,如果您使用更多LED并且它们将绘制的电流量超过上述限制,则必须使用单独的5V电源。在这种情况下,您还需要将两条地线彼此连接起来。此外,建议在Arduino和LED灯条数据引脚之间使用大约330欧姆的电阻,以降低该线路上的噪声,以及5V和地线上大约100uF的电容,以平滑电源。


示例1 - Arduino控制WS2812B LED示例

现在作为一个例子,我将使用20个LED长条,通过330欧姆电阻连接到Arduino,并使用单独的5V电源供电,如上所述。 对于Arduino的编程,我们将使用FastLED库。 这是一个优秀且文档齐全的库,可以轻松控制WS2812B LED。

Arduino-and-WS2812B-Example-1.jpg

此示例所需的组件:

●   WS2812B LED灯带

●   Arduino开发板

●   5V 6A直流电源


以下是第一个例子的Arduino源代码:

  1. #include <FastLED.h>
  2. #define LED_PIN     7
  3. #define NUM_LEDS    20
  4. CRGB leds[NUM_LEDS];
  5. void setup() {
  6.   FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);
  7.   
  8. }
  9. void loop() {
  10.   
  11.   leds[0] = CRGB(255, 0, 0);
  12.   FastLED.show();
  13.   delay(500);  
  14.   leds[1] = CRGB(0, 255, 0);
  15.   FastLED.show();
  16.   delay(500);
  17.   leds[2] = CRGB(0, 0, 255);
  18.   FastLED.show();
  19.   delay(500);
  20.   leds[5] = CRGB(150, 0, 255);
  21.   FastLED.show();
  22.   delay(500);
  23.   leds[9] = CRGB(255, 200, 20);
  24.   FastLED.show();
  25.   delay(500);
  26.   leds[14] = CRGB(85, 60, 180);
  27.   FastLED.show();
  28.   delay(500);
  29.   leds[19] = CRGB(50, 255, 20);
  30.   FastLED.show();
  31.   delay(500);
  32. }
复制代码

代码解释:首先我们需要包括FastLED库,定义LED灯带的数据所连接的引脚,定义LED的数量,以及定义CRGB类型的数组。 此类型包含LED,三个红色、绿色和蓝色通道中的每一个都有三个单字节数据成员。

在setup函数部分,我们只需要使用上面定义的参数初始化FastLED。 现在在主循环中,我们可以随时控制我们的LED。 使用CRGB函数,我们可以使用红色、绿色和蓝色三种参数将任何LED设置为任何颜色。 为了在LED上进行更改,我们需要调用函数FastLED.show()


示例2 - Arduino控制WS2812B LED制作动画

使用一些“for”循环,我们可以轻松制作一些动画。

Arduino-and-WS2812B-Example-2.jpg

以下是第二个例子的Arduino源代码:

  1. #include <FastLED.h>
  2. #define LED_PIN     7
  3. #define NUM_LEDS    20
  4. CRGB leds[NUM_LEDS];
  5. void setup() {
  6.   FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);
  7. }
  8. void loop() {
  9.   for (int i = 0; i <= 19; i++) {
  10.     leds[i] = CRGB ( 0, 0, 255);
  11.     FastLED.show();
  12.     delay(40);
  13.   }
  14.   for (int i = 19; i >= 0; i--) {
  15.     leds[i] = CRGB ( 255, 0, 0);
  16.     FastLED.show();
  17.     delay(40);
  18.   }
  19. }
复制代码

这里第一个“for”循环点亮所有20个蓝色LED,从第一个LED到最后一个LED,延迟40毫秒。 下一个“for”循环再次点亮所有20个LED,但这次是红色,反之,从最后一个LED到第一个LED。

FastLED库具有许多其他功能,可用于制作非常有趣的动画和灯光秀,因此只有您的想象力才能让您的下一个LED项目大放异彩。

跳转到指定楼层
风筝
发表于: 2018-11-7 20:40:48 | 显示全部楼层

使用WS2812B LED的交互式LED咖啡桌

现在让我们来看看在开始时提到的DIY交互式LED咖啡桌项目。这是我与Creativity Hero的Marija之间的合作项目。

Creativity-Hero-Interactive-LED-coffe-table.jpg

您可以查看她的网站文章,在那里她解释制作桌子的整个过程,从切割和组装木结构,到焊接和连接所有电子部件。在这里,我将解释电子部件如何工作,如何构建自定义Android应用程序和编程Arduino开发板。


以下是该项目的完整电路原理图。

Creativity-Hero-Interactive-LED-Coffee-Table-Circuit-Schematic.png

因此,该原理图由45个可寻址LED灯、45个红外接近传感器和一个HC-05蓝牙模块组成,所有这些都连接到Arduino Mega开发板。该电路由5V/6A电源供电。

该示例所需的组件:

●    WS2812B LED灯带

●    红外接近传感器

●    HC-05蓝牙模块

●    Arduino开发板

●    5V 6A直流电源.


以下是该项目的Arduino代码,如果我们排除蓝牙颜色控制功能,可以注意到代码实际上非常简单。

  1. #include "FastLED.h"
  2. #define NUM_LEDS 45
  3. #define LED_PIN 2
  4. #define COLOR_ORDER GRB
  5. CRGB leds[NUM_LEDS];
  6. void setup() {
  7.   FastLED.addLeds<WS2812, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS);
  8.   FastLED.setBrightness(brightness);
  9.   // Set the 45 proximity sensors pins as inputs, from digital pin 3 to pin 48
  10.   for (int pinNo = 0 + 3; pinNo <= 45 + 3; pinNo++) {
  11.     pinMode(pinNo, INPUT);
  12.   }
  13. }
  14. void loop() {
  15.   for (int pinNo = 0; pinNo <= NUM_LEDS-1; pinNo++) {
  16.     leds[pinNo] = CRGB( 0, 255, 0);    // Set all 45 LEDs to green color
  17.     // If an object is detected on top of the particular sensor, turn on the particular led
  18.     if ( digitalRead(pinNo + 3) == LOW ) {
  19.       leds[pinNo] = CRGB( 0, 0, 255); // Set the reactive LED to bluee
  20.     }
  21.   }
  22.   FastLED.show(); // Update the LEDs
  23.   delay(20);
  24. }
复制代码

代码描述:如前所述,首先我们需要定义基本参数,然后将45个接近传感器引脚设置为输入。

在使用单个“for”循环的主循环中,我们将所有LED设置为特定颜色,并检查接近传感器是否检测到对象。如果检测到,或者本例中为低逻辑状态,则特定的反应颜色将被设置为特定的LED。最后,使用FastLED.show()函数更新LED颜色。

要包含蓝牙色彩控制功能,我们需要添加更多代码行以及。


制作Android应用程序

以下是Android应用程序的工作原理。它由我们可以拾取颜色的调色板图像、两个检查按钮组成,我们可以从中选择是将所选颜色应用于反应LED还是背景LED,以及用于调整亮度的滑块。

Interactive-LED-Table-Custom-Build-Android-Application.jpg

如果我们看看应用程序的块,我们可以看到当我们触摸放置调色板图像的画布时会发生什么。使用.GetPixelColor块我们获取拾取颜色的红色、绿色和蓝色值,并使用蓝牙SendText块我们以文本形式将此信息发送到Arduino。

LED-Table-Android-App-Blocks.jpg

根据所选复选框,我们会发送不同的第一个字符或标记,这有助于在Arduino上接收文本时。当我们改变滑块的位置时会发生同样的情况,一个从10到100的值以文本形式发送到Arduino,前面带有标记“3”。


以下是Arduino代码:

  1. #include <SoftwareSerial.h>
  2. #include "FastLED.h"
  3. #define NUM_LEDS 45
  4. #define LED_PIN 2
  5. #define COLOR_ORDER GRB
  6. CRGB leds[NUM_LEDS];
  7. SoftwareSerial Bluetooth(53, 52); // Arduino(RX, TX) - Bluetooth (TX, RX)
  8. // Initial background color
  9. int backR = 100;
  10. int backG = 50;
  11. int backB = 10;
  12. // Initial reactive color
  13. int reactiveR = 10;
  14. int reactiveG = 50;
  15. int reactiveB = 100;
  16. int brightness = 50; // Initial brightness
  17. String dataIn = "";
  18. void setup() {
  19.   FastLED.addLeds<WS2812, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS);
  20.   FastLED.setBrightness(brightness);
  21.   Serial.begin(38400);
  22.   Bluetooth.begin(38400); // Default baud rate of the Bluetooth module
  23.   for (int pinNo = 0 + 3; pinNo <= 45 + 3; pinNo++) {
  24.     pinMode(pinNo, INPUT);
  25.   }
  26. }
  27. void loop() {
  28.   if (Bluetooth.available() > 0) {
  29.     dataIn = Bluetooth.readString();
  30.     delay(20);
  31.     if (dataIn.startsWith("1")) {
  32.       delay(10);
  33.       String stringR = dataIn.substring(dataIn.indexOf("R") + 1, dataIn.indexOf("G"));
  34.       reactiveR = stringR.toInt();
  35.       String stringG = dataIn.substring(dataIn.indexOf("G") + 1, dataIn.indexOf("B"));
  36.       reactiveG = stringG.toInt();
  37.       String stringB = dataIn.substring(dataIn.indexOf("B") + 1, dataIn.indexOf("E"));
  38.       reactiveB = stringB.toInt();
  39.     }
  40.     else if (dataIn.startsWith("2")) {
  41.       String stringR = dataIn.substring(dataIn.indexOf("R") + 1, dataIn.indexOf("G"));
  42.       backR = stringR.toInt();
  43.       String stringG = dataIn.substring(dataIn.indexOf("G") + 1, dataIn.indexOf("B"));
  44.       backG = stringG.toInt();
  45.       String stringB = dataIn.substring(dataIn.indexOf("B") + 1, dataIn.indexOf("E"));
  46.       backB = stringB.toInt();
  47.     }
  48.     else if (dataIn.startsWith("3")) {
  49.       String stringBrightness = dataIn.substring(dataIn.indexOf("3") + 1, dataIn.length());
  50.       brightness = stringBrightness.toInt();
  51.       FastLED.setBrightness(brightness);
  52.     }
  53.   }
  54.   for (int pinNo = 0; pinNo <= NUM_LEDS-1; pinNo++) {
  55.     leds[pinNo] = CRGB( backR, backG, backB);
  56.     if ( digitalRead(pinNo + 3) == LOW ) {
  57.       leds[pinNo] = CRGB( reactiveR, reactiveG, reactiveB);
  58.     }
  59.   }
  60.   FastLED.show();
  61.   delay(20);
  62. }
复制代码

代码描述:首先,我们需要定义Arduino开发板和HC-05蓝牙模块之间的串行通信,或模块所连接的引脚。在setup函数部分,我们需要设置此模块工作的波特率。然后在主循环中,使用Bluetooth.available()函数,我们检查是否有来自智能手机的传入数据。如果有,使用Bluetooth.readString()函数我们将数据作为字符串接收。然后使用.startsWith()函数检查第一个字符或标记,以此方式知道我们是否要更改反应颜色、背景或亮度。

使用.substring()函数,我们从接收的文本中提取红色、绿色和蓝色值,并将它们转换为整数。然后在下面的“for”循环中使用这些值,如前所述,它设置颜色并点亮LED。我们以同样的方式调整LED的亮度。


以上就是本教程的全部内容。如果遇到任何问题,请随时在本帖下面进行回复。

回复

使用道具 举报

再见慕斯唐
发表于: 2019-5-10 11:50:22 | 显示全部楼层

想知道arduino应用程序的所有细节,可否楼主发我学习一下,邮箱:994017120@qq.com
回复

使用道具 举报

风筝
发表于: 2019-5-15 19:53:59 | 显示全部楼层

本文使用的Android应用程序,以及MIT App Inventor工程文件:

DIY_Reactive_LED_Table.rar (208.01 KB, 下载次数: 81)

DIY_Reactive_LED_Table_Control.part2.rar (599.76 KB, 下载次数: 73)

DIY_Reactive_LED_Table_Control.part1.rar (1.9 MB, 下载次数: 126)

回复

使用道具 举报

vickerS
发表于: 2020-2-22 18:41:42 | 显示全部楼层

不表明原作者吗
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

主题 700 | 回复: 1477



手机版|

GMT+8, 2024-3-19 14:52 , Processed in 0.087858 second(s), 6 queries , Gzip On, MemCache On. Powered by Discuz! X3.5

YiBoard一板网 © 2015-2022 地址:河北省石家庄市长安区高营大街 ( 冀ICP备18020117号 )

快速回复 返回顶部 返回列表