查看: 52052 | 回复: 2

发表于: 2021-11-15 15:59:20 | 显示全部楼层

在这篇文章中，我们决定制作一个基于PID控制器的加热器，可用于控制3D打印机热端的温度，或者通过稍微修改设备，它可以非常有效地控制直流烙铁的温度，甚至经过更多点的调整，您可以控制晶闸管实现控制交流电机或交流加热元件的转速，PID控制的领域是无限可能的。

什么是温度PID控制器？

顾名思义，温度PID控制器处理温度，PID温度控制是一种闭环控制算法，可以提高过程的准确性。 PID温度控制使用数学公式来计算当前温度和设定值之间的差异。然后它会尝试提供所需的功率以确保目标温度保持恒定，这不仅减少了对环境的影响，还减少了传统开关控制机制中可能出现的过冲。

温度PID控制器如何工作？

就像在任何 PID 控制中一样，我们首先需要知道输出或我们希望控制器做什么，对于这个项目，我们希望保持加热元件的某个温度，所以为了保持温度，我们需要读出温度，为此我们使用K型热电偶，结合MAX6675冷端补偿K型热电偶到数字转换器IC，可以测量数百摄氏度没有任何问题。来自热电偶的温度读数作为反馈。现在我们已经设置了我们想要达到的温度并且我们有温度值的实时读数，控制器可以计算误差值，并且在比例积分和微分控制的帮助下，系统可以实现它的目标，对于这个项目我们将使用计算出的输出值控制PWM信号。这就是基于温度的PID控制器的工作原理。

MAX6675 K型热电偶IC的工作过程

热电偶的作用是感应热电偶导线两端的温差。热电偶的热结可以在 0°C 至 +1023.75°C 范围内读取。冷端（安装 MAX6675 的电路板的环境温度）只能在 -20°C 至 +85°C 的范围内。在冷端温度波动的同时，MAX6675继续准确感应对端的温差。 MAX6675通过冷端补偿检测并校正环境温度的变化。该器件使用温度感应二极管将环境温度读数转换为电压。为了进行实际的热电偶温度测量，MAX6675测量来自热电偶输出和检测二极管的电压。该器件的内部电路将二极管的电压（感测环境温度）和热电偶电压（感测远程温度减去环境温度）传递给存储在 ADC 中的转换函数，以计算热电偶的热结温度。当热电偶冷端和MAX6675处于相同温度时，MAX6675可实现最佳性能。 MAX6675包括信号调理硬件，可将热电偶的信号转换为与ADC输入通道兼容的电压。 T+ 和 T 输入连接到内部电路，以减少从热电偶线引入的噪声误差。

所需的组件

下面列出了构建基于 MAX6675 的 PID 控制加热器所需的组件，我们使用非常通用的组件设计了该电路，这使得复制过程非常容易。

● Arduino Nano开发板

● 12864 OLED显示屏模块

● 通用旋转编码器

● MAX6675 模块

● K型热电偶

● 面包板

● 连接导线

Components-Required-to-Build-PID-Enabled -ncoder-Motor-Controller.jpg

PID使能温度控制器电路图

在本文中，我们使用MAX6675 K型热电偶传感器从热电偶读取温度数据，在本节中，我们将借助原理图解释所有组件。MAX6675是冷端补偿 K 型热电偶到数字转换器模块，它根据原理图连接到Arduino。使用Arduino的+5V电源为电路供电。此外，为了设置温度和更改模式，我们使用通用旋转编码器。接下来，我们使用12864 OLED显示屏显示温度数据，还可以显示设定温度。一如既往，我们使用Arduino开发板作为项目的主控。通过按下旋转编码器上的按钮，我们可以在两种模式之间切换，一种是设置温度，另一种是从热电偶监测温度。

电梯直达

相关帖子

使用道具举报

风筝

发表于: 2021-11-15 16:26:15 | 显示全部楼层

沙发

基于MAX6675的PID温度控制器代码

首先您可以从下面给出的链接下载PID控制器库、MAX6675库、AAdafruit_SSD1306库，或者您可以使用开发板管理器方法安装库。

● 下载适用于Arduino的PID控制器库

● 下载适用于Arduino的MAX6675库

● 下载适用于Arduino的Adafruit_SSD1306库

代码非常简单，在本节中，我们将进行讲解。首先，包含所有必需的库，然后定义读取编码器、驱动OLED和MAX6675热电偶温度传感器所需的引脚编号。完成后，我们定义Kp、Ki 和 Kd 的所有值，以及所有必需的变量。

接下来，在代码中定义了 __Kp、__Ki 和 __Kd 值。这三个常量负责为我们的代码设置输出响应。请注意，对于这个项目，我使用了试错法来设置常量，但如果您的项目需要的话，您可以计算这些值。

/*In this section we have defined the gain values for the
* proportional, integral, and derivative controller I have set
* the gain values with the help of trial and error methods.
*/
#define __Kp 30 // Proportional constant
#define __Ki 0.7 // Integral Constant
#define __Kd 200 // Derivative Constant

复制代码

接下来，我们声明所有必需的变量并创建三个实例，一个用于PID，一个用于OLED，最后一个用于热电偶。变量clockPin和clockPinState、debounce和encoder_btn_count这四个用于从编码器读取数据， temperature_value_c保存了热电偶的温度读数，最后encoder_btn_count保存了编码器按钮被按下的次数。

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <PIDController.h>
#include "max6675.h"
// Define Rotary Encoder Pins
#define CLK_PIN 3
#define DATA_PIN 4
#define SW_PIN 2
// MAX6675 Pins
#define thermoDO 8
#define thermoCS 9
#define thermoCLINE 10
// Mosfet Pin
#define mosfet_pin 11
// Serial Enable
#define __DEBUG__
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define OLED_RESET -1 // Reset pin # (or -1 if sharing Arduino reset pin)
int clockPin; // Placeholder por pin status used by the rotary encoder
int clockPinState; // Placeholder por pin status used by the rotary encoder
int set_temperature = 1; // This set_temperature value will increas or decreas if when the rotarty encoder is turned
float temperature_value_c = 0.0; // stores temperature value
long debounce = 0; // Debounce delay
int encoder_btn_count = 0; // used to check encoder button press
MAX6675 thermocouple(thermoCLK, thermoCS, thermoDO); // Create an instance for the MAX6675 Sensor Called "thermocouple"
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);// Create an instance for the SSD1306 128X64 OLED "display"
PIDController pid; // Create an instance of the PID controller class, called "PID"

复制代码

接下来，在setup()函数中，首先我们启用串口监视器进行调试，Serial.begin() 法可以用#ifdef和#endif语句包装，以便我们可以在代码完成后轻松禁用串口监视器。

void setup() {
#ifdef __DEBUG__
Serial.begin(9600);
#endif

复制代码

接下来，我们将所有必需的引脚设置为项目工作所需的输入和输出。

pinMode(mosfet_pin, OUTPUT); // MOSFET output PIN
pinMode(CLK_PIN, INPUT); // Encoer Clock Pin
pinMode(DATA_PIN, INPUT); //Encoder Data Pin
pinMode(SW_PIN, INPUT_PULLUP);// Encoder SW Pin

复制代码

接下来，我们通过调用PID实例的begin()方法来初始化 PID 控制器。然后使用setpoint()方法添加设定点，PID算法将尝试通过控制输出来达到该值。接下来，我们调用tune()方法，这是我们放置 __Kp、__Ki 和 __Kd 的所有值的地方。最后，我们为 PID 控制器设置了一个极限值，这个极限值将允许计算输出在范围内，这确保计算输出不会超过我们的PWM值255的特定值。

pid.begin(); // initialize the PID instance
pid.setpoint(150); // The "goal" the PID controller tries to "reach"
pid.tune(__Kp, __Ki,__Kd); // Tune the PID, arguments: kP, kI, kD
pid.limit(0, 255); // Limit the PID output between 0 and 255, this is important to get rid of integral windup!

复制代码

接下来，我们检查是否有可用的显示屏，如果显示屏可用，代码将继续，如果显示不可用，它将打印错误。

if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
#ifdef __DEBUG__
Serial.println(F("SSD1306 allocation failed"));
#endif
for (;;); // Don't proceed, loop forever
}

复制代码

接下来，我们设置显示屏，首先旋转显示屏并在显示屏上播放启动画面，接下来我们擦除显示，使用setTextSize和setTextColour设置为白色。接下来，我们将光标设置在不同的位置并在显示屏上打印 PID Temperatur Control，然后延时2秒结束。

display.setRotation(2); //Rotate the Display
display.display(); //Show initial display buffer contents on the screen -- the library initializes this with an Adafruit splash screen.
display.clearDisplay(); // Cleear the Display
display.setTextSize(2); // Set text Size
display.setTextColor(WHITE); // set LCD Colour
display.setCursor(48, 0); // Set Cursor Position
display.println("PID"); // Print the this Text
display.setCursor(0, 20); // Set Cursor Position
display.println("Temperatur"); // Print the this Text
display.setCursor(22, 40); // Set Cursor Position
display.println("Control"); // Print the this Text
display.display(); // Update the Display
delay(2000); // Delay of 200 ms

复制代码

在set_temp()函数中，我们设置加热器的温度，并检查按钮状态，如果状态为2，那么我们首先擦除显示设置文本大小，并将设置的温度打印在显示上。read_encoder()函数读取编码器并检查编码器是顺时针还是逆时针旋转，如果编码器顺时针旋转，我们增加计数器如果编码器逆时针旋转我们减少。最后，我们还通过编码器按钮检查编码器按钮状态，我们可以在温度设置模式和监控模式之间切换。

void set_temp(){
if (encoder_btn_count == 2) // check if the button is pressed twice and its in temperature set mode.
{
display.clearDisplay(); // clear the display
display.setTextSize(2); // Set text Size
display.setCursor(16, 0); // set the diplay cursor
display.print("Set Temp."); // Print Set Temp. on the display
display.setCursor(45, 25); // set the cursor
display.print(set_temperature);// print the set temperature value on the display
display.display(); // Update the Display
}
}
void read_encoder() // In this function we read the encoder data and increment the counter if it is rotating clockwise and decrement the counter if it's rotating counterclockwise
{
clockPin = digitalRead(CLK_PIN); // we read the clock pin of the rotary encoder
if (clockPin != clockPinState && clockPin == 1) { // if this condition is true then the encoder is rotaing counter clockwise and we decremetn the counter
if (digitalRead(DATA_PIN) != clockPin) set_temperature = set_temperature - 3; // decrmetn the counter.
else set_temperature = set_temperature + 3; // Encoder is rotating CW so increment
if (set_temperature < 1 )set_temperature = 1; // if the counter value is less than 1 the set it back to 1
if (set_temperature > 150 ) set_temperature = 150; //if the counter value is grater than 150 then set it back to 150
#ifdef __DEBUG__
Serial.println(set_temperature); // print the set temperature value on the serial monitor window
#endif
}
clockPinState = clockPin; // Remember last CLK_PIN state
if ( digitalRead(SW_PIN) == LOW) //If we detect LOW signal, button is pressed
{
if ( millis() - debounce > 80) { //debounce delay
encoder_btn_count++; // Increment the values
if (encoder_btn_count > 2) encoder_btn_count = 1;
#ifdef __DEBUG__
Serial.println(encoder_btn_count);
#endif
}
debounce = millis(); // update the time variable
}
}

复制代码

在loop()函数中我们调用read_encoder() 和set_temp() 函数，这些函数会被不断调用，在该循环中，我们还会检查按钮模式，如果设置为1，我们从热电偶读取温度并放入它通过PID实例的计算方法。计算完成后，我们直接将计算值放入输出PWM 信号的模拟写入函数中。一切都完成后，我们只需更新显示。

void loop()
{
read_encoder(); //Call The Read Encoder Function
set_temp(); // Call the Set Temperature Function
if (encoder_btn_count == 1) // check if the button is pressed and it's in Free Running mode -- in this mode, the Arduino continuously updates the screen and adjusts the PWM output according to the temperature.
{
temperature_value_c = thermocouple.readCelsius(); // Read the Temperature using the readCelsius methode from MAX6675 Library.
int output = pid.compute(temperature_value_c); // Let the PID compute the value, returns the optimal output
analogWrite(mosfet_pin, output); // Write the output to the output pin
pid.setpoint(set_temperature); // Use the setpoint methode of the PID library to
display.clearDisplay(); // Clear the display
display.setTextSize(2); // Set text Size
display.setCursor(16, 0); // Set the Display Cursor
display.print("Cur Temp."); //Print to the Display
display.setCursor(45, 25);// Set the Display Cursor
display.print(temperature_value_c); // Print the Temperature value to the display in celcius
display.display(); // Update the Display
#ifdef __DEBUG__
Serial.print(temperature_value_c); // Print the Temperature value in *C on serial monitor
Serial.print(" "); // Print an Empty Space
Serial.println(output); // Print the Calculate Output value in the serial monitor.
#endif
delay(200); // Wait 200ms to update the OLED dispaly.
}
}